#東方弾幕風
#Title[ＱＥＤ「495年の波紋」]
#Text[フランちゃんかわいいよウフフ]
#Player[REIMU, MARISA]
#PlayLevel[EX]
#ScriptVersion[2]

script_enemy_main {

@Initialize{
	SetScore(5000000);
	SetTimer(120);
	SetShotAutoDeleteClip(10,10,10,10);
	let img="script\img\ExRumia.png";
	SetLife(8400);
	SetMovePosition02(GetCenterX,GetClipMinY+80,60);
	LoadGraphic(img);
	SetTexture(img);
	SetText("ＱＥＤ「495年の波紋」");
	SetEffectForZeroLife(60,10,10);
	main;
}

	@MainLoop {
		yield;
	}
	
	@DrawLoop {
		if(GetSpeedX==0){SetGraphicRect(0,0,64,64);}
		else if(GetSpeedX>0){SetGraphicRect(192,0,256,64);}
		else{SetGraphicRect(128,0,192,64);}
		DrawGraphic(GetX,GetY);
		if(OnBomb){
			SetAlpha(0);
		}else{
			SetAlpha(255);
		}
	}

	@Finalize {
	}

	task main{
		yield;
		COLLISION;
		shot;
	}

	task COLLISION{
		loop{
			if(OnBomb){
				SetDamageRate(0,0);
				SetCollisionA(GetPlayerX,GetPlayerY,0);
			}else{
				SetDamageRate(100,0);
				SetCollisionA(GetX,GetY,24);
			}
		SetCollisionB(GetX,GetY,24);
		wait(1);
		}
	}

	task shot{
		wait(80);
		let way=90;
		let span=4;
		loop{
			let angle=rand_int(0,4);
			let x=rand_int(GetX-100,GetX+100);
			let y=rand_int(GetY-30,GetY+30);
			let waitHP=40+GetEnemyLife/35;
			let speed=2.5-GetEnemyLife/5600;
			if(GetTimer<=30){
				waitHP=40;
				speed=2.5;
			}
			loop(way){
				obj_shot(x,y,speed,angle);
				angle-=span;
			}
			wait(waitHP);
		}
	}

	task obj_shot(let set_x,let set_y,let speed,let angle){
		let obj=Obj_Create(OBJ_SHOT);
		ObjShot_SetGraphic(obj,BLUE11);
		Obj_SetPosition(obj,set_x,set_y);
		Obj_SetSpeed(obj,speed);
		Obj_SetAngle(obj,angle);
		wait(30);
		let count=0;
		while(!Obj_BeDeleted(obj)){
			if (count < 1) {
				if (Obj_GetX(obj)<=GetClipMinX) {
					Obj_SetAngle(obj,180-Obj_GetAngle(obj));count++;
				}
				if (Obj_GetX(obj)>=GetClipMaxX) {
					Obj_SetAngle(obj,180-Obj_GetAngle(obj));count++;
				}
				if (Obj_GetY(obj)<=GetClipMinY) {
					Obj_SetAngle(obj,-Obj_GetAngle(obj));count++;
				}
			}
			wait(1);
		}
	}

	function wait(let wait) {
		loop (wait) {yield;}
	}
}